Windows Server: Server Manager non elabora i dati. Errore 0x80041002 (WBEM_E_NOT_FOUND)

Il Server Manager non carica nessun ruolo e non consente di visualizzare alcuna informazione.

Sintomi

Il servizio WMI è corrotto e non consente il caricamento dei dati. L’errore che viene visualizzato è il seguente 0x80041002.

l’errore “0x80041002 (WBEM_E_NOT_FOUND)” si verifica quando si prova ad aprire uno spazio dei nomi WMI in un computer che utilizza Windows 7 o Windows Server 2008 R2 – Supporto tecnico Microsoft

Viene inoltre visualizzato nel registro eventi di Server-Manager

Si applica a tutte le versioni di Windows Server.

Risoluzione

È necessario resettare il servizio WMI e riconfigurare tutti i moduli di caricamento delle informazioni di controllo della strumentazione.

Scaricare il file batch reset-wmi.bat

Di seguito il codice contenuto nel file.

@echo off
cls
echo Disabilitazione Servizio Windows Management Instrumentation
sc config winmgmt start= disabled

echo Arresto Servizio Windows Management Instrumentation
net stop winmgmt /y

echo Registrazione librerie Windows Management Instrumentation
%systemdrive%
cd %windir%\system32\wbem
for /f %%s in ('dir /b *.dll') do regsvr32 /s %%s
for /f %%s in ('dir /b *.exe') do regsvr32 /s %%s

cd %windir%\sysWOW64\wbem
for /f %%s in ('dir /b *.dll') do regsvr32 /s %%s
for /f %%s in ('dir /b *.exe') do regsvr32 /s %%s

cd %windir%\system32\wbem

echo Registrazione Servizio Windows Management Instrumentation
wmiprvse /regserver 
winmgmt /resetrepository

echo Abilitazione Servizio Windows Management Instrumentation
sc config winmgmt start= auto

echo Avvio Servizio Windows Management Instrumentation
net start winmgmt

echo Registrazione moduli Windows Management Instrumentation
cd %windir%\system32\wbem
for /f %%s in ('dir /s /b *.mof *.mfl') do mofcomp %%s

cd %windir%\sysWOW64\wbem
for /f %%s in ('dir /s /b *.mof *.mfl') do mofcomp %%s

echo Registrazione completata.

Eseguire, da una finestra Prompt di Comandi in modalità amministratore il file scaricato.

Al termine riavviare Server Manager ed attendere il caricamento.